Computeralgebra in der Physik

(ein interaktives Tutorium von Martin Ziegler)

 

Inhaltsverzeichnis

  1. Einleitung
  2. Erste Schritte
  3. Raumfahrt
  4. Netzwerktheorie
  5. Wheatstonesche Brücke
  6. Mechanik
  7. Katastrophenschutz
  8. Ägyptologie
  9. Quantenmechanik
  10. Unschärferelation
  11. Kugelkoordinaten
  12. Barometrische Höhenformel
  13. Theoretische Mechanik
  14. Leichtathletik
  15. Schwingungslehre
  16. Schwingungslehre II
  17. Kinematik
  18. Vektoranalysis
  19. Elektrostatik
  20. Atomphysik
  21. Hydrodynamik
  22. Elektromagnetische Wellen
  23. Helmholz-Spulen
  24. Kontinuumsmechanik
  25. Pendel mit Überschlag
  26. Differentialgeometrie
  27. Normalmodenanalyse
  28. Apfelmännchen
  29. Linearer Meßdaten-Fit
  30. Nichtlinearer Meßdaten-Fit
  31. Quantenfeldtheorie

1. Einleitung

Im Gegensatz zu numerischer Mathematik befaßt Computeralgebra sich mit symbolischer Formelmanipulation, d.h. alle Berechnungen erfolgen exakt und unter Berücksichtigung freier Parameter. Diese Eigenschaften sind von besonderer Bedeutung für den Einsatz in der Physik. Andererseits fällt der Einstieg in die Computeralgebra oftmals schwer: Die meisten Einführungen richten sich erfahrungsgemäß an ein eher mathematisch orientiertes Publikum mit Interesse an Zahlentheorie, Polynomen und Zerfällungskörpern.

Um dem abzuhelfen, habe ich am hiesigen Fachbereich Physik vor Studentinnen und Studenten nach dem Vordiplom ein Tutorium "Computeralgebra in der Physik" gehalten. Ziel war es, Geschmack zu wecken anhand von Beispielen aus der physikalischen Praxis. Gelöst wurden sie mit dem an der Universität-Gesamthochschule Paderborn von der AG Prof. Fuchssteiner entwickelten System MuPAD. MuPAD (Multi Processing Algebra Data) ähnelt Maple, ist jedoch frei verfügbar, objektorientiert und unterstützt Parallelrechner.

Neben dieser WWW-Seite gibt es das Tutorium auch als Postscript-Dokument. Zum Nachrechnen der Beispiele benötigen Sie außerdem die Dateien fit.mu und fit.dat.

Zusätzlich ist es auch als 'interaktives Buch' verfügbar in Form eines HyTeX-Dokuments. Kopieren Sie dazu

in Ihre lokale MuPAD- Installation unter ./doc/hytex/ beziehungsweise .\doc\dvi\   und die Graphiken nach ./doc/hytex/gif/physik/   beziehungsweise .\doc\dvi\gif\physik\
Letzteres Unterverzeichnis muß eventuell erst noch erstellt werden...

Die Aufgaben-Reihenfolge entspricht der steigenden Vielfalt und Komplexität der zur Lösung eingesetzten MuPAD-Befehle, nicht der der zugrundeliegenden Physik!

Viel Spaß
wünscht Martin


2. Erste Schritte

Übersetzen Sie die folgenden mathematischen Operationen in MuPAD-Befehle und führen Sie diese aus!

(1 + 5/2 * 3) / (1/7 + 7/9)^2;

(1 + 5/2 * 3) / (1/7 + 7/9)^2;

x:=3.14159265,  y:=sin(x)

x:=3.14159265;   y:=sin(x);

x:=pi,  y:=sin(x)

x:=PI:   y:=sin(x);

{ t e IR : 3t^2 + 7t + 1/2 = 0 }

solve( 3*t^2 + 7*t + 1/2 = 0 , t );


3. Raumfahrt

Eine Rakete fliegt mit konstanter linearer Beschleunigung so, daß ihre Bewohner das gleiche Gewicht wie auf der Erde spüren. In welcher Zeit erreichen sie den Mars (150 Mio km) und welche Endgeschwindigkeit wird dabei erreicht?

Lösung:   a=g,  s(t)=1/2 a t^2,  v(t)=at

a:=9.81:   s:=150*10^9:   solve( s=1/2*a*t^2 , t);
t:=op(%,1):   t/60/60/24;   v:=a*t;

Die Reise dauert etwas über zwei Tage. Die Endgeschwindigkeit von ca. 1700 km/sec zeigt, daß relativistische Effekte dabei noch vernachlässigt werden können.


4. Netzwerktheorie

Bestimmen Sie den Gesamtwiderstand Rg des folgenden Widerstandnetzwerkes für R0=R1=R2=R3=R4=R5=R, indem Sie die Symmetrie des Problems berücksichtigen. Lösen Sie die Aufgabe auch allgemein, d.h. für beliebige Teilwiderstände, und vergleichen Sie die Ergebnisse.
Schaltplan eines Widerstandsnetzwerks

Lösung: Im ersten Fall muß R4 aus Symmetriegründen stromlos sein. Man kann ihn weglassen und erhält die folgende Parallelschaltung mit Gesamtwiderstand RG=R/2:

Parallelschaltung von 2R, R und 2R

Im allgemeinen Fall lesen wir aus dem Netzwerk mittels Kirchhoffs Knoten- und Maschenregel jeweils drei Gleichungen ab für beliebigen aber festen Gesamtstrom IG und geben sie in MuPAD ein:

{ I1*R1-I3*R3-I4*R4 = 0,
     I0*R0-I3*R3-I5*R5 = 0,
     I0*R0-I1*R1-I2*R2 = 0,
     I2 = I1 + I4,
     I3 = I4 + I5,
     I0 + I2 + I5 = IG }:
   solve( % , {I0,I1,I2,I3,I4,I5} ):
   op(%,1):   assign(%):

Nun kennen wir insbesondere den Strom I0; damit aber auch die gesuchte Gesamt-Spannung UG=I0R0. Division durch den Gesamtstrom IG liefert das Ergebnis RG=UG/IG:

I0*R0/IG:   RG:=Factor(simplify(%));

R0 (R1 R2 R3 + R1 R2 R5 + R1 R3 R4 + R1 R3 R5 + R2 R3 R4 + R1 R4 R5 + R2 R3 R5 + R2 R4 R5) / (R0 R1 R2 + R0 R1 R4 + R0 R2 R3 + R0 R1 R5 + R0 R2 R4 + R1 R2 R3 + R0 R3 R4 + R0 R3 R5 + R1 R2 R5 + R1 R3 R4 + R0 R4 R5 + R1 R3 R5 + R2 R3 R4 + R1 R4 R5 + R2 R3 R5 + R2 R4 R5)

und f"ur Ri=R wird RG zu

subs(RG,R0=R,R1=R,R2=R,R3=R,R4=R,R5=R);


5. Wheatstonesche Brücke

Wie groß ist der Strom I0 durch R0?

Über den regelbaren Widerstand R3 läßt sich I0=0 erreichen: die Brücke ist jetzt abgeglichen. Bestimmen Sie nun den unbekannten Widerstand RX als Funktion der anderen Widerstände. Kann man dieses Verfahren in der Praxis verwenden zur hochpräzisen Widerstandsmessung, ohne den Innenwiderstand R0 des Strommeßgeräts zu kennen?

Lösung:

{ IG = I1+I3 ,
     I1=I2+I0 ,
     IG = I2+IX ,
     R1*I1+I0*R0-I3*R3 = 0 ,
     I0*R0+IX*RX-I2*R2 = 0 }:
   solve(%,{I0,I1,I2,I3,IX}):
   op(%):   assign(%):
   generate::TeX(I0):   print(Unquoted,%):

I0 = (R2 R3 IG - R1 IG RX) / 
  (R0 R1 + R0 R2 + R0 R3 + R1 R2 + R2 R3 + R0 RX + R1 RX + R3 RX)

solve(I0=0,RX):   RX=op(%);

Für die abgeglichene Brücke hängt das RX nicht von R0 ab.


6. Mechanik

Berechnen Sie das Trägheitsmoment J einer homogenen Kugel mit Masse m und Radius R bei Rotation um ihren Mittelpunkt.

Lösung: In Kugelkoordinaten ist

J=Volumenintegral ueber r^2 rho dV,
   dV=r^2 sin(v) dr df dv=4 pi r^2 dr

wobei rho sich aus m=4/3 pi R^3 rho ergibt.

rho := m/(4/3*PI*R^3):
    J  := int( r^2*rho*4*PI*r^2 , r=0..R );


7. Katastrophenschutz

Berechnen Sie die kinetische Energie Ek eines Wirbelsturms als rotierendem Zylinder mit Radius R, Höhe H und Randgeschwindigkeit v bei gegebener Dichte rho.
Wie viele Jahre müßte ein Kernkraftwerk (1 Gigawatt) laufen, um einen realistischen Wirbelsturm R=30km, H=6km, v=180 km/h, rho=1.2kg/m^3 zu entzwirbeln?

Lösung: Es ist Ek=J*omega2/2 mit der Winkelgeschwindigkeit omega und dem Trägheitsmoment in Zylinderkoordinaten

J=Volumenintegral r^2 rho dV
 = VolIntegral r^2 rho r f dr df dz
  = int( 2 pi H rho r^3 , r=0..R )

J:=int( 2*PI*H*rho*r^3,r=0..R ):   w:=v/R:   E_k:=J*w^2/2;

T:=float(E_k/P):   P:=10^6:   R:=30000:   v:=180000/3600:
   H:=6000:   rho:=1.2:   T:    %/60:   %/60:   %/24:   %/365;


8. Ägyptologie

Berechnen Sie Volumen V und potentielle Energie Ep einer Pyramide mit Grundfläche A0 und Höhe H unter der Annahme einer konstanten Massendichte rho.
Für die Große Pyramide ist A0=(250m)2, H=161m, rho=2.3 g/cm^3. Wie lange müßte ein Kraftwerk mit 60MW Leistung laufen, um die gleiche Energie aufzubringen?

Lösung: Sei A(h) die Fläche eines Querschnitts durch die Pyramide auf der Höhe h=0..H, d.h. A(0)=A0 und A(H)=0. Gemäß Strahlensatz sind in diesen Schnitten alle Längenverhältnisse konstant, d.h. A(h) selbst geht quadratisch in h, und zwar unabhängig von der Form der Grundfläche. Benutzen wir nun das Cavallieri-Prinzip zur Berechnung des Volumens:

A(h):=(1-h/H)^2*A_0:     V:=int(A(h),h=0..H);

Die potentielle Energie dE einer solchen Schnittfläche A(h) mit infinitesimaler Dicke dh ist gegeben durch dE=mgh mit m=rho A(h) dh (Dichte mal Volumen).

dE:=rho*A(h)*g*h:     Ep:= int( dE , h=0..H );

Bei gegebener, konstanter Leistung P dauert die Erbringung dieser Arbeit T=Ep/P, also für die oben angegebenen Werte in SI-Einheiten:

T:=Ep/P:   g:=9.81:   A_0:=250^2:   H:=161:
   rho:=2.3*(100)^3/1000:   P:=60*10^6:   T;

Umrechnung von Sekunden in Minuten und Stunden:

%/60:   %/60;


Der Rest

Die folgenden Abschnitte des Tutoriums schöpfen die MuPAD-Funktionalität an Graphik, Rechenzeit und Speicher voll aus und laufen daher nicht mehr unter der eingeschränkten Online Demo-Version im WWW. Bitte benutzen Sie statt dessen Ihre lokale MuPAD-Installation oder downloaden Sie eine aktuelle Release für Ihren Rechner.